Here's an awk script to normalise the I/Q signal to the
RMS amplitude.

#!/usr/bin/awk -f

BEGIN{
   idx = 0;
   sum_square = 0
}
{
   stamp[idx] = $1
   ival[idx] = $2
   qval[idx] = $3

   sum_square += $2*$2 + $3*$3
   idx++

   if( idx == 300)
   {
      rms = sqrt( sum_square/idx)

      for( i = 0; i < idx; i++)
         printf( "%s %.5e %.5e\n", stamp[i], ival[i]/rms, qval[i]/rms)
      idx = 0;
      sum_square = 0
   }
}


Make sure the 'shebang' line is the first line of the script.

Save it in a file, say, iqnorm.

Make the file executable with: chmod +x iqnorm

Then pipe the raw ASCII signal through it, so that instead of

 vtwavex 26.wav | vtraw -oa | ebnaut -dp16K21A ...

you run

 vtwavex 26.wav | vtraw -oa | ./iqnorm | ebnaut -dp16K21A ...

I've run it on my recordings (sample rate 1Hz) of the 5char
transmissions and every single one has improved Eb/N0.

Not yet tried it on the W1VD, K3SIW files.

The '300' means 300 samples, so that's 300 * 0.45723950 ~= 137 seconds
for the W1VD files, or 231.5 seconds for K3SIW.

--
Paul Nicholson
--